Анатолий Беляев (aka Mr.ALB). Персональный сайт

1. Отсутствие регулировки яркости индикатора.
2. Отсутствие гашения незначащего нуля.

/*************************************************************
 * 2018-05-25 Mr.ALB
 *
 * Основа взята с сайта:
 * http://arduinolab.pw/index.php/2016/06/23/chasy-na-arduino/
 * Часы на 7 сегментном индикаторе TM1637
 * и модуле реального времени RTC DS3231
 * 
 * Модуль RTC DS3231:
 * SCL – A5
 * SDA – A4
 * SQW – 2  – Для мигания разделительных точек
 * VCC – 5V
 * GND – GND
 * 
 * Подключить кнопки управления на пины и на GND
 * 
 * 2018-11-20 Запись значения яркости в EEPROM
 * 2018-11-22 Гашение незначащего нуля
 * 2020-01-02 Доработка считывания яркости из EEPROM
 * 2020-05-06 Доработка считывания из EEPROM
 *************************************************************/

#include <EEPROM.h>    // для EEPROM
#include <Wire.h>
#include "TM1637.h"

// 7 сигментный индикатор TM1637
#define CLK 6         
#define DIO 7
TM1637 tm1637(CLK,DIO); // Создание объекта индикатора

// Кнопки установки времени
#define buttonHour 5  // Часы
#define buttonMin  4  // Минуты
#define buttonSet  3  // Установка
#define buttonBR   8  // Кнопка яркости

// Адрес часов реального времени
#define DS3231_I2C_ADDRESS 0x68 

byte brightness = 1;  // Яркость, от 1 до 7
byte addrBR = 6;      // Адрес в EEPROM для записи яркости
boolean flag_br = false;// Флаг для записи яркости
boolean flag_null=false;// Флаг для гашения незначащего нуля
volatile boolean flag;  // Переменная для прерывания

/**********************
 **** Подпрограммы ****
 **********************/
/* часы .. */
byte decToBcd(byte val)
{
  return ((val/10*16) + (val%10));
}

byte bcdToDec(byte val)
{
  return ((val/16*10) + (val%16));
}

/* Установка данных в модуль RTC DS3231 */
void setDateDs3231
  (
    byte second,      // 0-59
    byte minute,      // 0-59
    byte hour,        // 1-23
    byte dayOfWeek,   // 1-7
    byte dayOfMonth,  // 1-28/29/30/31
    byte month,       // 1-12
    byte year         // 0-99
  )
{
   Wire.beginTransmission(DS3231_I2C_ADDRESS);
   Wire.write(0);
   Wire.write(decToBcd(second));    
   Wire.write(decToBcd(minute));
   Wire.write(decToBcd(hour));     
   Wire.write(decToBcd(dayOfWeek));
   Wire.write(decToBcd(dayOfMonth));
   Wire.write(decToBcd(month));
   Wire.write(decToBcd(year));
   Wire.endTransmission();
}

/* Получение данных с модуля RTC DS3231 */
void getDateDs3231
  (
    byte *second,
    byte *minute,
    byte *hour,
    byte *dayOfWeek,
    byte *dayOfMonth,
    byte *month,
    byte *year
  )
{
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  Wire.write(0);
  Wire.endTransmission();

  Wire.requestFrom(DS3231_I2C_ADDRESS, 7);

  *second     = bcdToDec(Wire.read() & 0x7f);
  *minute     = bcdToDec(Wire.read());
  *hour       = bcdToDec(Wire.read() & 0x3f); 
  *dayOfWeek  = bcdToDec(Wire.read());
  *dayOfMonth = bcdToDec(Wire.read());
  *month      = bcdToDec(Wire.read());
  *year       = bcdToDec(Wire.read());
}

/* Включаем выход SQW,
 * который вроде выключен по умолчанию 
 */
void setINT()
{    
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  Wire.write(0x0E);
  Wire.write(0x0);
  Wire.endTransmission();
}

/* Для мигания точек */
void blink()
{
  digitalWrite(LED_BUILTIN,!digitalRead(LED_BUILTIN));
  flag = !flag;
  tm1637.point(flag); 
}

void setup() 
{
  Wire.begin();
  // Для мигания точек
  pinMode(LED_BUILTIN, OUTPUT);
  // Кнопка изменения часов
  pinMode(buttonHour, INPUT_PULLUP);
  // Кнопка изменения минут
  pinMode(buttonMin, INPUT_PULLUP);
  // Кнопка разрешения установок
  pinMode(buttonSet, INPUT_PULLUP);
  // Кнопка изменения яркости 
  pinMode(buttonBR, INPUT_PULLUP);
   
  // Инициализация индикатора
  tm1637.init();
  
  // Включаем выход SQW на RTC3231
  setINT();

  // Установка начальной яркости
  tm1637.set(brightness);
  
  // Установка значений из EEPROM
  // Считывание яркости из EEPROM 
  byte setBR = EEPROM.read(addrBR);
  if(setBR >= 0 && setBR < 8 && setBR != brightness) tm1637.set(setBR);

   // Подключаем прерывание 0 на пин 2
  attachInterrupt(0, blink, CHANGE);
  
   // Или подключаем прерывание 1 на пин 3
   // Тогда убрать строчки с прерыванием 0
   // attachInterrupt(1, blink, CHANGE);
}

void loop()
{
  byte second,
       minute,
       hour,
       dayOfWeek,
       dayOfMonth,
       month,
       year;
  
  // Читаем время из модуля
  getDateDs3231
   (
     &second,
     &minute,
     &hour,
     &dayOfWeek,
     &dayOfMonth,
     &month, 
     &year
   ); 
  
  // Заполняем массив значениями
  // для отпарвки на индикатор
  int8_t TimeDisp[4];
  
  TimeDisp[0] = hour / 10;  // Десятки часов
  TimeDisp[1] = hour % 10;  // Единицы часов
  TimeDisp[2] = minute / 10;// Десятки минут
  TimeDisp[3] = minute % 10;// Единицы минут

  /* Обработка кнопок
   * Изменения при одновременном совместном нажитии
   * на кнопку buttonSet
   */
  if(
      !digitalRead(buttonHour) &&
      !digitalRead(buttonSet)
     )
  { // Часы
    // сбрасываем секунды
    second = 0;
    // прибавляем единицу к часам
    hour++;

    // если вылезли за границы присваеваем 0
    if(hour > 23) hour = 0;
    // записываем в модуль
    setDateDs3231
     (
      second,
      minute,
      hour,
      dayOfWeek,
      dayOfMonth,
      month,
      year
     );
    delay(200);
  }
  
  if(
      !digitalRead(buttonMin) &&
      !digitalRead(buttonSet)
     )
  { // Минуты
    second = 0;
    minute++;
    if(minute > 59) minute = 0;
    setDateDs3231
     (
       second,
       minute,
       hour,
       dayOfWeek,
       dayOfMonth,
       month,
       year
     );

    delay(200);
  }
  
  if(
      !digitalRead(buttonBR) &&
      !digitalRead(buttonSet)
     )
  { // Яркость индикатора
    brightness++; 
    if (brightness > 7) brightness = 1; 

    tm1637.set(brightness);
    flag_br = true;
    delay(200); 
  }
  
  if(
      flag_br==true &&
      digitalRead(buttonSet)==HIGH
     )
  { // Запись значения в EEPROM
    // при отжатой кнопке buttonSet
    flag_br=false;
    EEPROM.write(addrBR, brightness);

    // Гашение экрана как индикация записи
    tm1637.clearDisplay();
    delay(900); 
  }
  
  // Отправляем массив на индикатор
  if(TimeDisp[0]!=0)
  { // Если первое значение не 0, то выводим
    if(flag_null)flag_null=false; // Сбросим флаг нуля
    tm1637.display(0,TimeDisp[0]);// Вывод первой цифры
  }
  else

  { // Иначе гашение незначащего нуля
    // Гасим один первый раз при смене на 0 
    if(!flag_null)
    {
      flag_null=true;       // Выставим флаг нуля
      tm1637.clearDisplay();// Гашение экрана
    }
  }
  
  tm1637.display(1,TimeDisp[1]);  // Вывод второй цифры
  tm1637.display(2,TimeDisp[2]);  // Вывод третьей цифры
  tm1637.display(3,TimeDisp[3]);  // Вывод четвёртой цифры
}