Автополив. PY32F002A1556

/***************************************************************
  2026-05-20 Mr.ALB Проверка PY32F002AL1556
  2026-06-24 Mr.ALB Автополив цветов - начало проекта
  2026-06-26 Mr.ALB Отладка
  2026-06-28 Mr.ALB Работает v1.0, проверка и оптимизация
  2026-06-29 по 2026-07-11 Проверка и отладка промежутка 
           между поливами. Добился очень точного повторения,
           срабатывает в одну и ту же минуту даже при поливе 
           через 2 дня
           
  PY32F002AL1556TU SOP-8
  -----------------------
                  +-\/-+
        VCC 3.3V 1|    |8 GND
        PA4/PA10 2|    |7 PA1/BTN - защита от сна
          RX/PA3 3|    |6 PA2/TX/PF2/!RST
  SWCLK/PA14/PB3 4|    |5 PA13/SWDIO
                  +----+

  НАСТРОЙКА среды
  ---------------
  board part number: PY32F002Ax5
  Optimize: Smallest (-Os) width LTO

  ПРОГРАММИРОВАНИЕ МК
  -------------------
  1. bin создать тут в Arduino IDE
  2. Через DAPLINK программой PuyaCoFlash-1.5.1 записать bin


  ПОДКЛЮЧЕНИЕ
  -----------
  BTN         PY32F002A1556
  1         - GND (pin8)
  2         - PA1 (pin7)

  LED
  A -[5.1k]- PA4 (pin2)
  K -------- GND (pin8)

  RST_BTN
  1        - PA2 (pin6)
  2        - GND (pin8)

  PUMP_in
  1 -[100]-- PA3 (pin3)
  PUMP_led
  A -[5.1k]- PA3 (pin3)
  K -------- GND (pin8)


  НАСТРОЙКА автополива
  --------------------
  1. Включить питание - засветится красный светодиод (настройка).
  2. Пока красный светодиод светится - нажать кнопку [настройка].
  3. Теперь красный светодиод будет поочерёдно промаргивать
     количество дней между поливами.
  4. После требуемого промежутка в днях - нажать кнопку [настройка].
  5. Включится насос (зелёный светодиод) и будет работать,
     пока не нажать кнопку [настройка], что ограничит время
     работы насоса, а иначе насос проработает максимальное время
     и сам остановится.
  6. Далее идёт запись в EEPROM. После чего красный светодиод
     моргнёт столько раз, сколько выбрано дней между поливами.
  7. После этого программа переходит к работе. Насос работает
     столько, сколько определено при настройке и переходит в режим
     ожидания следующего полива.
  8. В момент ожидания кратко промаргивает красный светодиод, что
     указывает на работу программы, остутствие зависания.
  9. Когда время ожидания закончилось, включается насос полива.
     После завершения работы насоса красный светодиод моргнёт
     продолжительно столько раз, сколько дней ожидания до
     следующего полива.
  10. Если нажать на кнопку [сброс-reset], то программа начнёт
     работу заново. Если при этом не нажимать кнопку [Настройка],
     то после гашения красного светодиода настройки, программа
     переходит к считыванию настроек из EEPROM и далее включает
     работу насоса. Потом переходит к ожиданию следующего полива
     через заданное ранее число дней.
     Это удобно для ручного принудительного полива.
  ---------------------------------------------------------------
  Скетч использует 10528 байт (51%) памяти устройства.
  Всего доступно 20480 байт.
  Глобальные переменные используют 1384 байт (45%) динамической
  памяти, оставляя 1688 байт для локальных переменных.
  Максимум: 3072 байт.

 ****************************************************************/
#include <EEPROM.h>       // Библиотека памяти
#include <PY32LowPower.h> // Библиотека сна

#define BTN       PA1     // Кнопка настройки
#define LED       PA4     // Светодиод настройки
#define PUMP      PA3     // Насос водяной

PY32LowPower lowPower;    // Создание объекта для сна
#define SLEEP_TM  4000    // Время сна 4000 мс = 4 c
#define EEP_ADR   3       // Адрес данных

#define MAX_PERIOD    3   // Максимальное число дней ожидания полива
#define DEF_WORK_TIME 3000// Время работы насоса по умолчанию 3 сек

// Если отладка не нужна, то закомментировать строчку ниже
//#define DEBUG           // Отладка

#ifdef DEBUG
// Настройка для отладки
// Множитель - дни в тики 10t => 10 тиков * 4 секунды = 40 секунд в день
#define MULTIPLIFIER    10    // 10 тиков на день
#define MAX_WORK_TIME   20000 // Макс.время работы насоса 20 секунд  
#else
// Настройка для работы
// Сутки 24 часа = 1440 минут = 86400 секунд
// 86400 секунд / 4 секунды сна = 21600 тиков в день
#define MULTIPLIFIER    21600   // Множитель - дни в тики
#define MAX_WORK_TIME   300000  // Макс.время работы насоса 5 минут
#define ADD_TICKS       165     // Поправка в день 163
#endif

// Структура данных
struct MyObject
{
  uint8_t  dni = 1;                   // Период в днях
  uint32_t work_time = DEF_WORK_TIME; // Время до конца работы в мс
};
MyObject myData;            // Объявляем переменную с данными

uint16_t tim;               // Для пауз
uint32_t period_ticks = 0;  // Время до конца периода в тиках
uint32_t count = 0;         // Счётчик тиков

/*****************************
 ***** Функция НАСТРОЙКИ *****
 ****************************/
void setup()
{
  // Защита от зависания во сне, для программирования МК
  // Если нажать кнопку перед включением, затем удерживать кнопку и
  // включить МК, то переход в безконечный цикл - можно программировать
  // Иначе кнопка далее используется для настройки полива
  pinMode(BTN, INPUT_PULLUP); // Подтяжка к питанию
  if (!digitalRead(BTN)) while (1);

  // Светодиод настройки
  pinMode(LED, OUTPUT);       // Определение пина на выход

  // Насос
  pinMode(PUMP, OUTPUT);     // Определение пина на выход
  digitalWrite(PUMP, LOW);   // Отключим насос

  /******************************************
    НАСТРОЙКА значений переменни автополива
   *****************************************/
  bool flag = false;         // Флаг нажатия кнопки
  digitalWrite(LED, HIGH);   // Включим светодиод настройки

  // Даём 2 секунды на решение по настройке
  tim = millis();
  while ((millis() - tim) < 2000)
  {
    // Если нажать кнопку BTN, то переход в настройку полива
    if (!digitalRead(BTN))
    {
      flag = true;  // Выставим флаг нажатия кнопки настройки
      break;        // Выход из цикла
    }
  }

  if (flag)  // Если нажата кнопка [Настройка]
  {
    flag = false;           // Сбросим флаг кнопки
    digitalWrite(LED, LOW); // Отключим красный сетодиод
    delay(1000);

    // Выбор времени ожидания в днях
    while (1) // Пока не нажата кнопка [Настройка]---------------
    {
      fnLedBlink(myData.dni, 500);    // Показ дней: 1,2,3
      tim = millis();
      while ((millis() - tim) < 1000) // Задержка 1 секунда
      {
        if (!digitalRead(BTN))        // Проверка нажатия кнопки
        {
          // Если нажата кнопка - выход из выбора дней
          flag = true;  // Выставим флаг нажатия кнопки
          break;
        }
      }
      if (flag)
        break;        // Выход из выбора дней
      else
        myData.dni++; // Переходим к следующему времени в днях

      // Ходим по кругу, пока не нажата кнопка [Настройка]
      if (myData.dni > MAX_PERIOD)myData.dni = 1;
    }
    // end of while(1)-------------------------------------------
    delay(1000);              // Задержка 1 секунда

    // Определяем время работы насоса
    tim = millis();
    myData.work_time = millis();
    digitalWrite(PUMP, HIGH); // Включаем насос

    // Задержка на работу насоса
    // Выход из задержки по кнопке или превышению времени работы
    while (digitalRead(BTN) && (millis() - tim) < MAX_WORK_TIME);

    // Вычисляем время работы насоса
    myData.work_time = millis() - myData.work_time; // В мс
    digitalWrite(PUMP, LOW);  // Отключаем насос
    delay(1000);              // Задержка 1 секунда

    // Запишем настройки в EEPROM
    EEPROM.put(EEP_ADR, myData);
    // Сигнал записи в EEPROM - моргаем число выбранных дней
    fnLedBlink(myData.dni, 500);
  }
  else  // Кнопка не нажата - загрузим данные из EEPROM
  {
    digitalWrite(LED, LOW);   // Отключим светодиод [Настройка]
    // Загрузить данные .dni, .work_time из EEPROM
    EEPROM.get(EEP_ADR, myData);
  }

  // Ограничения-----------------------------------
  if (myData.dni > MAX_PERIOD) myData.dni = 1;
  if
  (
    myData.work_time > MAX_WORK_TIME ||
    myData.work_time < DEF_WORK_TIME
  )
    // Время работы по умолчанию 3 секунды
    myData.work_time = DEF_WORK_TIME;
  //-----------------------------------------------

  // Вычислим время ожидания полива в тиках
  period_ticks = myData.dni * MULTIPLIFIER; //
  period_ticks += myData.dni * ADD_TICKS; // Поправка в тиках

  // Вычтем время работы насоса из общего числа тиков
  //period_ticks -= myData.work_time / SLEEP_TM;
  //2026-07-01 Опытным путём определилось, что время до следующего
  // полива за сутки на 5 минут меньше, поэтому убрал учёт времени
  // работы насоса из period_ticks, будет ближе к 1440 минутам

  count = period_ticks; // Ожидание полива в тиках -> счётчик

  fnPumpOperation();    // Работа насоса
  lowPower.begin();     // Установка функции сна
}
// end of setup()

/****************************
 ***** Функция: РАБОТА ******
 ****************************/
void loop()
{
  if (!count)           // Время ожидания закончилось
  {
    fnPumpOperation();  // Работа насоса
    // Возобновим время ожидания в тиках
    count = period_ticks;
  }

  lowPower.deepSleep(SLEEP_TM); // Сон на SLEEP_TM мс
  count--;                      // Уменьшаем после каждого сна
  // Показ работы программы после пробуждения - нет зависания
  fnLedBlink(myData.dni, 1);
}
// end of loop()


/**************************
   Подпрограммы / Функции
 **************************/

/***********************************************
  Функция: Мигалка настроечным светодиодом
    num - количество переключений,
    tm  - размер паузы
***********************************************/
void fnLedBlink(uint8_t num, uint8_t tm)
{
  bool f = HIGH;
  for (byte i = 0; i < num * 2; i++)
  {
    digitalWrite(LED, f); // Светодиод вкл./откл.
    delay(tm);
    f = !f;               // Меняем значение на обратное
  }
}
// end of fnLedBlink()

/*********************************************
   Функция: Работа насоса
 ********************************************/
void fnPumpOperation(void)
{
  digitalWrite(PUMP, HIGH); // Включим насос
  delay(myData.work_time);  // Время работы насоса
  digitalWrite(PUMP, LOW);  // Отключим насос

  // Сигнал  - моргаем число дней до след. полива
  fnLedBlink(myData.dni, 500);
}
// fnPumpOperation()