Анатолий Беляев (aka Mr.ALB). Персональный сайт

/***********************************************************
  *  Проверка работоспособности EEPROM
  *  2019-10-22 Mr.ALB v1
  *  2019-11-19 Mr.ALB v2 Переделка функции fnTxRx
  *   Для вывода сообщений на русском языке в
  *   Мониторе порта - установите кодировку скетча
  *   в UTF-8
  *   2020-03-23 Mr.ALB v2.1 Добавил для ATMega2560
  *   2022-02-16 Mr.ALB v3 автоматическое определение
  *   2022-02-17 Mr.ALB v3 Автоматическое определение
  *                       размера EEPROM
  *                       через функцию length() для AVR
  *                       и через функцию size() для LGT8F
**********************************************************/
// Для Работы с AVR закомментируйте строку ниже
//#define USE_LGT_EEPROM_API  // Для работы с LGT8F
#include <EEPROM.h>

byte val, val_rx;
int  count_error = 0;
int  EEPROM_max;
int  address;
char choice; // Переменная выбора действия

void setup()
{
  //Установка начала псевдослучайного числа
  randomSeed(analogRead(1));

  // Инициализация порта для монитора
  Serial.begin(9600);
  while (!Serial);

  // Автоматическое определение максимального размера EEPROM
#if defined(USE_LGT_EEPROM_API)
  EEPROM_max = EEPROM.size();   // Для LGT8F
#else
  EEPROM_max = EEPROM.length(); // Для AVR
#endif

  Serial.println(F("Проверка Arduino EEPROM Test v3.1"));
  Serial.println(F("http://mralb.ru/sections/programming/arduino_10.php"));
  Serial.print(F("Размер EEPROM: "));
  Serial.println(EEPROM_max);
}

void loop()
{
  Serial.println();
  Serial.println(F("Выбор действия: Отправить значение в порт"));
  Serial.println(F("1. Проверка всех ячеек EEPROM"));
  Serial.println(F("2. Проверка EEPROM выборочно"));
  Serial.println(F("3. Очистить весь EEPROM"));

  // Читаем значение из последовательного порта
  while (1)
  {
    choice = Serial.read();

    if (choice == '1')
    {
      Serial.println(F("Выбрано: проверка EEPROM"));
      fnCheckEEPROM();
      break;
    }
    if (choice == '2')
    {
      Serial.println();
      Serial.println(F("Выбрано: проверка EEPROM выборочно"));
      address = 26;
      byte s = fnTxRx(address, random(0, 256));
      break;
    }

    if (choice == '3')
    {
      Serial.println(F("Выбрано: Очистить EEPROM"));
      fnClearEEPROM();
      break;
    }
  }
}

/******************************
   Проверка всех ячеек EEPROM
 *****************************/
void fnCheckEEPROM()
{
  // Перебор всех ячеек EEPROM в цикле
  for (int i = 0; i < EEPROM_max; i++)
  {
    val = random(0, 256); // Случайное число
    // Записываем val и считываем val_rx по адресу i
    val_rx = fnTxRx(i, val);

    // Проверим совпадение записанного и считанного
    if (val != val_rx)
    { // Если записанное число не совпадает со считанным
      Serial.print(F("\t"));
      Serial.println(F("Не совпадает!")); // Сообщение
      count_error++;
    }
  }

  // Вывод сообщения о результате проверки
  Serial.println();
  Serial.println(F("Версия программы v3.1"));
  Serial.println(F("Проверка EEPROM завершена."));
  if (count_error > 0)
  {
    Serial.print(F("Повреждено: "));
    Serial.print(count_error);
    Serial.println(F(" ячеек EEPROM"));
    Serial.println(F("В них считанные значения не совпадают с записанными."));
  }
  else
  {
    Serial.print(F("Считанные значения совпадают"));
    Serial.println(F(" с записанными во всех ячейках EEPROM."));
  }
}

/**************************
  Очистка EEPROM
  записываем в ячейки 255
***************************/
void fnClearEEPROM()
{
  Serial.println();
  Serial.println(F("Очистка EEPROM"));
  for (int i = 0; i < EEPROM_max; i++)
  {
    Serial.print(i);
    Serial.print(F("\t"));
    Serial.print(F("Было: "));
    Serial.print(EEPROM.read(i));
    Serial.print(F("\t"));
    EEPROM.write(i, 255); // Записываем число 255/0xFF в EEPROM
    Serial.print(F("Стало: "));
    Serial.println(EEPROM.read(i));
  }
  Serial.println();
  Serial.println(F("Очистка EEPROM завершена."));
}


/* Функция записи и считывания числа в и из EEPROM */
byte fnTxRx(int i, byte v)
{
  byte v_rx, eData;

  Serial.print(i);
  Serial.print(F("\t"));
  Serial.print(F("Было: "));
  eData = EEPROM.read(i);   // Начальное число в ячейке
  Serial.print(eData);
  Serial.print(F("\t"));

  EEPROM.write(i, v);      // Записываем число в EEPROM
  Serial.print(F("Записано: "));
  Serial.print(v);         // Выводим записанное число
  Serial.print(F("\t"));

  v_rx = EEPROM.read(i);   // Считываем записанное число из ячейки
  Serial.print(F("считано: "));
  Serial.print(v_rx, DEC); // Выводим десятичное значение
  Serial.print(F("\t"));

  EEPROM.write(i, eData);  // Записываем начальное число в EEPROM

  Serial.print(F("Восстановлено: "));
  Serial.println(EEPROM.read(i));

  return v_rx;
}